Local background correction

Prerequisites

Before starting this lesson, you should be familiar with:

• Median filter

• Projections

Learning Objectives

After completing this lesson, learners should be able to:

• Understand how to use image filters for creating a local background image

• Use the generated local background image to compute a foreground image

Motivation

Very often, biological images contain locally varying background intensities. This hampers both segmentation and intensity quantification. However, often it is possible to generate a background image that can be subtracted in order to yield a foreground image with zero background. It is very important to know about this, because removing spatially varying background is a prevalent task in bioimage analysis.

Concept map

Figure

Activities

• Activity 1 - Background subtraction using a median filter.
  • Open image xy_8bit__some_spots_with_uneven_bg
  • Compute a background image using a median filter
  • Create a foreground image by subtracting the background image from the input image
  • (Optional) Segment the spots in the foreground image.
• Activity 2 - Background subtraction using a maximum intensity projection.
  • Open image xyt_8bit_polyp
  • Create a maximum intensity projection of this image.
    • Because the polyp is moving around and is darker than the background this will create a background image.
  • Create a foreground image by subtracting the maximum intensity projection from the original image.

Activity 1 ImageJ GUI

• Open image xy_8bit__some_spots_with_uneven_bg
• [ Image › Rename… ]
  • “input”
• Create background image
  • [ Image > Duplicate…]
  • [ Process > Filters > Median… ]
    • radius = 15
  • [ Image › Rename… ]
    • “background”
• Create foreground image
  • [ Process › Image Calculator… ]
    • Image 1 = input
    • Subtract
    • Image 2 = background
    • create
    • 32-bit
  • [ Image › Rename… ]
    • “foreground”

Activity 1 ImageJ Macro

/**
 * Fiji script for local background subtraction 
 */

// Parameters (please modify)
//
medianFilterRadius = 15;

// Code (rather not modify)
//
run("Close All");

// Open data
open("https://github.com/NEUBIAS/training-resources/raw/master/image_data/xy_8bit__some_spots_with_uneven_bg.tif");
rename("input");

// Create background image
run("Duplicate...", "title=background");
run("Median...", "radius="+medianFilterRadius);
rename("background");

// Create foreground image
imageCalculator("Subtract create 32-bit", "input","background");
rename("foreground");

run("Tile");

// Create line profiles for a more quantitative visualisation of the process
makeLine(99,200,81,121,82,87,91,64,230,26);
selectWindow("foreground");
run("Plot Profile");

// Also create the same line profiler on the input image
selectWindow("input");
run("Restore Selection");
run("Plot Profile");

Activity 2 ImageJ GUI

• Open image xyt_8bit_polyp
• Make a maximum intensity projection to create a background image ([Image › Stacks › Z Project…])
• Use the image calculator function [ Process › Image Calculator…] to subtract the maximum intensity projection from the original:
  • Image1: xyt_8bit_polyp
  • Operation: Subtract
  • Image2: MAX_xyt_8bit_polyp
  • ‘create new window’
  • ‘32-bit float result’
  • Say ‘yes’ to the ‘Process entire stack’ message.

Activity 2 ImageJ Macro

// Open image
open("https://github.com/NEUBIAS/training-resources/raw/master/image_data/xyt_8bit_polyp.tif");
// Create maximum intensity projection
run("Z Project...", "projection=[Max Intensity]");
// Subtract maximum intensity projection from original image
imageCalculator("Subtract create 32-bit stack", "xyt_8bit_polyp.tif","MAX_xyt_8bit_polyp.tif");

Activity 2 ImageJ Jython

# Use a maximum intensity projection for background subtraction

# import packages
from ij import IJ
from ij.plugin import ZProjector, ImageCalculator

# open image
imp = IJ.openImage("https://github.com/NEUBIAS/training-resources/raw/master/image_data/xyt_8bit_polyp.tif")

# create maximum intensity projection
maxproj = ZProjector().run(imp, "max all")

# subtract maximum intensity projection from original image
background_subtracted = ImageCalculator().run(imp, maxproj, "Subtract create 32-bit stack")

# show all images
imp.show()
maxproj.show()
background_subtracted.show()
IJ.run("Tile")

Exercises

• Spots in a cell
  • Open xy_16bit__autophagosomes_crop.tif
  • Create a background image by duplicating the input image and applying a median filter to it.
    • Choose the radius of the median filter just large enough such that the bright spots dissappear.
  • Create the foreground image by subtracting the background image from the input image.
    • You should see an image with the bright spots, now without the uneven background.

ImageJ GUI

• Open the autophagosomes input image (s.a.)
• [ Image › Rename… ]
  • “input”
• [ Image › Duplicate… ]
  • title = “median”
• [ Process › Filters › Median…]
  • radius = 7
• [ Image › Rename… ]
  • “background”
• [ Process › Image Calculator… ]
  • “input”
  • Subtract
  • “background”
  • create
  • 32-bit
• [ Image › Rename… ]

ImageJ Macro

a = 1;
run("Close All");
open("https://github.com/NEUBIAS/training-resources/raw/master/image_data/xy_16bit__autophagosomes_crop.tif");
rename("input");
run("Duplicate...", "title=median");
run("Median...", "radius=7");
rename("background");
imageCalculator("Subtract create 32-bit", "input", "background");
rename("foreground");
run("Tile");

Assessment

True or false?

1. Mean filter is better than the median filter to generate a background image.
2. On the generated background image the objects of interest should not be visible.
3. When creating a background image by means of filtering: The size of the filter’s structuring element should be much smaller than the size of the objects.

Solution

1. False (mean filter is really quite poor in terms of removing foreground information)
2. True (because this is the background image, so it should not contain any foreground information)
3. False (it should be much (maybe ~3 times) larger in order to remove the objects from the image)

Follow-up material

Recommended follow-up modules:

Learn more: